Truly measuring from one point to another on a model is close to
impossible, because of the structure of the language. Modules are
black holes; you can't get any information out of them.
However, here's a measuring stick that you can drop into your
model. If you position it so that it lines up with the two points,
you can read off the dimension.
It doesn't have any actual numeric markings; instead, it has black
marks every once in a while that you can count. You can set the
interval, or it'll automatically pick a power-of-ten interval based
on how far away the camera is at refresh. Adding numbers wouldn't
be too hard. Note that it's only visible if you set $measure true.
module measuringstick(len, interval=pow(10,floor(log($vpd)-1)), center=false) {
if (!is_undef($measure) && $measure) {
r = 0.5;
mark = interval * 0.01;
%translate([0, 0, center ? -len/2 : 0]) {
for (z=[0:interval:len]) {
mark1 = min(len-z, mark/2);
if (mark1 > 0) {
translate([0,0,z]) color("black") cylinder(r=r, h=mark/2);
}
z2 = z + mark1;
block = min(len-z2, interval-mark);
if (block > 0) {
translate([0,0,z2]) cylinder(r=r, h=block);
}
z3 = z2 + block;
mark2 = min(len-z3, mark/2);
if (mark2 > 0) {
translate([0,0,z3]) color("black") cylinder(r=r, h=mark/2);
}
}
}
}
}
//$measure=true;
rotate([10,0,0]) measuringstick(100);
_______________________________________________
OpenSCAD mailing list
To unsubscribe send an email to
[hidden email]
Locked
