Best way to draw a funnel

Hello, first-off I'm fairly new to openscad.

I'd like to draw a funnel with a smooth, e.g. arc, transition between the cone and the pipe.  What would be the best way to code this?

Thanks
Simon

That's a little tricky. I guess you could make a donut shape, then a cone tangent to the surface going up, and a cylinder tangent to the surface going down. Do that twice with different sizes by the thickness, and difference them.

BTW your post is still flagged as "This post has NOT been accepted by the mailing list yet", you may want to check your registration.

I'd have a look at rotate_extrude, generate the shape, then spin it around the axis to complete the funnel.

Simple example with a straight line:

rotate_extrude()
  translate([2,0]) // need to ensure it is all in the X+ quadent, also makes the hole.
    rotate(45)
      square([25,1]);

Then workout a curvey shape; a little harder.

The best way to get tangents is with hull().

bowl = 50;
bowl_r = 50;
stem = 60;
stem_r = 5;
neck_r = 10;
thickness = 2;

curve_r = 10;

$fa = 5;
$fs = 0.1;
eps = 0.01;

module profile() {
        hull() {
                translate([stem_r, 0])
                        square([thickness, eps]);

                translate([neck_r + curve_r, stem])
                        circle(r = curve_r);
               
                translate([bowl_r, stem + bowl - eps])
                        square([thickness, eps]);
        }
}

rotate_extrude()
        difference() {
                profile();
                translate([thickness, 0])
                        profile();
        }

Great, thanks for all your replies.  I'll tease apart the instructions to figure out exactly how its working.

I was pretty sure I'd tried to subscribe but didn't get the promised email.  Have tried again.

Cheers
Simon