Absaugstutzen



Following Jordan Brown's scheme ...

$fn=24;

tube(3,10,1)
  curve(10,3,30,1)
    adapter(5,3,2.5,1)
      tube(2.5,7,1);


module curve(R,r,angle,thick,n=10) {
  translate([-R,0,0])
    rotate([-90,0,0]) {
      difference() {
        $fm = $fn;
        rotate_extrude(angle=angle,$fn=360/angle*n)
          translate([R,0])
            circle(r,$fn=$fm);
        rotate(-1)
          rotate_extrude(angle=angle+2,$fn=$fn*4)
            translate([R,0])
              circle(r-thick);
      }
      rotate(angle)
        translate([R,0,0])
          rotate([90,0,0])
            children();
    }
}

module tube(r,length,thick,r2) {
  r2 = is_undef(r2)? r: r2;
  translate([0,0,-length/2])
    difference() {
      cylinder(r1=r,r2=r2,h=length,center=true);
      cylinder(r1=r-thick,r2=r2-thick,length+.001,center=true);
    }
  translate([0,0,-length]) children();
}

module adapter(length,r1,r2,thick,n=10) {
    translate([0,0,-length*(1-1/n)])
    for(i=[1:n-1]) {
      x1 = r2 + (r1-r2)*(-2*i/(n-1)+3)*pow(i/(n-1),2);
      x2 = r2 + (r1-r2)*(-2*(i-1)/(n-1)+3)*pow((i-1)/(n-1),2);
      translate([0,0,i*length/n])
        tube(x2,length/n,thick,x1);
    }
    children();
}

Em dom., 6 de jun. de 2021 às 14:56, <[hidden email]> escreveu:

Liebe Leute
Ich möchte gerne einen Absaugstutzen modellieren... der ein Knie hat (ca. 30°) und dessen beide Durchmesser verschieden groß sind.

Wiewohl blutiger Anfänger mit Openscad hatte ich in den vergangenen Monaten eine recht steile Lernkurve... Aber diese Anforderung... da bin ich echt überfordert.
Vielen Dank
Karl
--
Diese Nachricht wurde von unterwegs gesendet...
_______________________________________________
OpenSCAD mailing list
To unsubscribe send an email to [hidden email]

_______________________________________________
OpenSCAD mailing list
To unsubscribe send an email to [hidden email]